Indice   FAQ  
Iscriviti  Login
Indice RouterOS Wiki routerOSiTalia [GUIDE]

Script puntamento - led/acustico - RB411/433

In questa sezione puoi trovare alcune guide su routerOS

Ti è stata utile questa guida?Dà il tuo giudizio

SI
6
100%
NO
0
Nessun voto
NON NE AVEVO BISOGNO
0
Nessun voto
 
Voti totali : 6

Script puntamento - led/acustico - RB411/433

Messaggioda figheras » ven 20 nov 2009, 15:06

Questo script è valido solo per le routerboard 411/433

Con questo script è possibile verificare il puntamento direttamende sulla nostra RB
sia attraverso i LED sia ascoltando il cicalino gia presente sulla scheda.

Di seguito il codice:
Codice: Seleziona tutto
# Mikrotik RB411/433 "Lights and Sound" alignment script
# written by Mark Shumate Feb 2009
#
# NOTE: This script may work on other platforms, I
# don't have anything but RB411/433 here in front of
# me. The beeps will probably work on practically any
# wireless AP type Routerboard, but maybe the script
# would have to be edited? Dunno if it complains when
# you reference LEDs that don't exist...
#
# This script recognizes 9 different "signal levels"
# and 3 assoc. statuses (connected, searching, other)
# Currently, "signal levels" indicate the SNR/margin
# measurement. Higher signal-to-noise measurements
# correspond to higher levels. So level 8 would be
# the best, below 1 would be the worst. The better
# the signal-to-noise, the more LEDs you get, and
# the faster the beeps get. Only 4 LEDs are used,
# (the 5th being left alone, for NAND access ind.)
# with intermediate signal levels resulting in a
# combination of solid and flashing LEDs, shown
# here:
#
# >= Level 8 : 4 solid (100ms beeps)
# >= Level 7 : 3 solid, 4th flashing (300ms beeps)
# >= Level 6 : 3 solid (500ms beep cycle)
# >= Level 5 : 2 solid, 3rd flashing (700ms beeps)
# >= Level 4 : 2 solid (900ms beeps)
# >= Level 3 : 1 solid, 2nd flashing (1100ms beeps)
# >= Level 2 : 1 solid (1300ms beeps)
# >= Level 1 : 1 flashing (1500ms beeps)
# <  Level 1 : no LEDs, beeps only (1700ms beeps)
#
# The user-LED (green LED above the blue power LED)
# is used to display the association status. If the
# wireless interface is associated, the user-LED is
# solid. If the wireless interface is actively
# searching, but not yet associated, the user-LED is
# blinking twice a second, with a pause while a
# rising trill of 3 beeps is played. If the wireless
# interface is neither associated, nor searching
# (like disabled, or something weird) then the light
# will flicker rapidly every 2 seconds, and a
# falling trill of 2 beeps is played.

# Finally, the script plays startup (rising) and
# shutdown (falling) tones.

# For reference, the delay times associated with the
# different signal levels are shown here:
#:local lnsdelaytime 100ms;  <---signals at/above lvl 8
#:local lnsdelaytime 300ms;  <---signals between 7 and 8
#:local lnsdelaytime 500ms;  <---signals between 6 and 7
#:local lnsdelaytime 700ms;  <---signals between 5 and 6
#:local lnsdelaytime 900ms:  <---signals between 4 and 5
#:local lnsdelaytime 1100ms; <---signals between 3 and 4
#:local lnsdelaytime 1300ms; <---signals between 2 and 3
#:local lnsdelaytime 1500ms; <---signals between 1 and 2
#:local lnsdelaytime 1750ms; <---signals below lvl 1
#:local lnsdelaytime 2000ms; <---signal not available

# default delaytime
:local lnsdelaytime "2000ms";

# name of wireless interface to monitor (default wlan1)
:local lnsintname "wlan1";

# frequency (as in pitch) of beep (recommend 700 - 1000)
:local lnsbeepfreq 800;

# Here, the different signal levels are assigned to
# signal-to-noise measurements. I haven't really tweaked
# these yet to be in line with field testing, so they
# may need quite a bit of adjusting.
:local lnslevel8 70;
:local lnslevel7 65;
:local lnslevel6 60;
:local lnslevel5 55;
:local lnslevel4 50;
:local lnslevel3 45;
:local lnslevel2 40;
:local lnslevel1 35;

# The (veery approximate, heh) running time of the script
# is set here. I am too lazy right now to do this a
# better way...besides, who cares if the thing beeps or
# flashes a couple extra minutes right?!? :)
:local lnsrunningtime 60m;

# Here, we set how long the script will beep. NOTE that
# startup/shutdown tones will still be played.
# I like this feature when using an access point where
# the LEDs are clearly visible. If you don't want this
# feature, set it to the same as $lnsrunningtime
# (above).
:local lnsbeeptime 10m;

# figure out beep cutoff time
:local lnsrunbeepdiff;
:set lnsrunbeepdiff ($lnsrunningtime - $lnsbeeptime);


# initialize LEDs, play starting tones
:delay 50ms;
:led user-led=no led4=no led3=no led2=no led1=no;
:delay 50ms;
:beep frequency=($lnsbeepfreq - 300) length=50ms;
:delay 50ms;
:beep frequency=($lnsbeepfreq - 200) length=50ms;
:delay 50ms;

# main monitoring cycle
:while ($lnsrunningtime > 0s) do={
  /interface wireless monitor "$lnsintname" once do={
    :if ($"status" = "connected-to-ess") do={
      :if ($"signal-to-noise" >= $lnslevel8) do={
        :set lnsdelaytime 100ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :led user-led=yes led4=yes led3=yes led2=yes led1=yes;
        :delay $lnsdelaytime;
      }
      :if ($"signal-to-noise" >= $lnslevel7 && $"signal-to-noise" < $lnslevel8) do={
        :set lnsdelaytime 300ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :for i from=1 to=3 do={
          :led user-led=yes led4=no led3=yes led2=yes led1=yes;
          :delay ($lnsdelaytime / 6);
          :led user-led=yes led4=yes led3=yes led2=yes led1=yes;
          :delay ($lnsdelaytime / 6);
        }
      }
      :if ($"signal-to-noise" >= $lnslevel6 && $"signal-to-noise" < $lnslevel7) do={
        :set lnsdelaytime 500ms;
        :led user-led=yes led4=no led3=yes led2=yes led1=yes;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :delay $lnsdelaytime;
      }
      :if ($"signal-to-noise" >= $lnslevel5 && $"signal-to-noise" < $lnslevel6) do={
        :set lnsdelaytime 700ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :for i from=1 to=3 do={
          :led user-led=yes led4=no led3=no led2=yes led1=yes;
          :delay ($lnsdelaytime / 6);
          :led user-led=yes led4=no led3=yes led2=yes led1=yes;
          :delay ($lnsdelaytime / 6);
        }
      }
      :if ($"signal-to-noise" >= $lnslevel4 && $"signal-to-noise" < $lnslevel5) do={
        :set lnsdelaytime 900ms;
        :led user-led=yes led4=no led3=no led2=yes led1=yes;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :delay $lnsdelaytime;
      }
      :if ($"signal-to-noise" >= $lnslevel3 && $"signal-to-noise" < $lnslevel4) do={
        :set lnsdelaytime 1100ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :for i from=1 to=3 do={
          :led user-led=yes led4=no led3=no led2=no led1=yes;
          :delay ($lnsdelaytime / 6);
          :led user-led=yes led4=no led3=no led2=yes led1=yes;
          :delay ($lnsdelaytime / 6);
        }
      }
      :if ($"signal-to-noise" >= $lnslevel2 && $"signal-to-noise" < $lnslevel3) do={
        :set lnsdelaytime 1300ms;
        :led user-led=yes led4=no led3=no led2=no led1=yes;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :delay $lnsdelaytime;
      }
      :if ($"signal-to-noise" >= $lnslevel1 && $"signal-to-noise" < $lnslevel2) do={
        :set lnsdelaytime 1500ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :for i from=1 to=3 do={
          :led user-led=yes led4=no led3=no led2=no led1=no;
          :delay ($lnsdelaytime / 6);
          :led user-led=yes led4=no led3=no led2=no led1=yes;
          :delay ($lnsdelaytime / 6);
        }
      }
      :if ($"signal-to-noise" < $lnslevel1) do={
        :set lnsdelaytime 1700ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=($lnsdelaytime / 2);
        }
        :led user-led=yes led4=no led3=no led2=no led1=no;
        :delay $lnsdelaytime;
      }
    } else={
      :if ($"status" = "searching-for-network") do={
        :set lnsdelaytime 2000ms;
        :led user-led=no led4=no led3=no led2=no led1=no;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=$lnsbeepfreq length=100ms;
        }
        :delay 100ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=($lnsbeepfreq + 100) length=75ms;
        }
        :delay 75ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=($lnsbeepfreq + 200) length=50ms;
        }
        :delay 50ms;
        :for i from=1 to=4 do={
          :led user-led=no;
          :delay ($lnsdelaytime / 8)
          :led user-led=yes;
          :delay ($lnsdelaytime / 8)
        }
        :set lnsdelaytime ($lnsdelaytime + (50ms + 75ms + 100ms));
      } else={
        :set lnsdelaytime 2000ms;
        :led user-led=no led4=no led3=no led2=no led1=no;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=($lnsbeepfreq - 150) length=150ms;
        }
        :delay 150ms;
        :if ($lnsrunningtime > $lnsrunbeepdiff) do={
          :beep frequency=($lnsbeepfreq - 350) length=100ms;
        }
        :delay 100ms;
        :for i from=1 to=4 do={
          :led user-led=yes;
          :delay 50ms;
          :led user-led=no;
          :delay 50ms;
        }
        :delay 1550ms;
      }
    }
  }
:set lnsrunningtime ("$lnsrunningtime" - "$lnsdelaytime");
}

# shut off LEDs, play shutdown tones
:delay 50ms;
:led user-led=no led4=no led3=no led2=no led1=no;
:delay 50ms;
:beep frequency=($lnsbeepfreq - 200) length=50ms;
:delay 50ms;
:beep frequency=($lnsbeepfreq - 300) length=50ms;
:delay 50ms;


Utilizzate la solita procedure per importarlo nella vostra RB
Siamo tutti ignoranti. Ma non tutti ignoriamo le stesse cose! - Einstein -
Avatar utente
figheras
Staff rosIT
Staff rosIT
 
Messaggi: 1218
Iscritto il: sab 19 set 2009, 20:09
Uso routerOS dalla Versione: v2.9.x
Certificazioni Mikrotik: MTCNA, MTCRE, MTCWE
Altre certificazioni: Cisco CCNA, KalliopePBX
Preferred Training Centre: Grifonline

Re: Script puntamento - led/acustico - RB411/433

Messaggioda figheras » ven 20 nov 2009, 15:35

Fabrizio vedi se va bene questo script per il tuo caso.... :D
Siamo tutti ignoranti. Ma non tutti ignoriamo le stesse cose! - Einstein -
Avatar utente
figheras
Staff rosIT
Staff rosIT
 
Messaggi: 1218
Iscritto il: sab 19 set 2009, 20:09
Uso routerOS dalla Versione: v2.9.x
Certificazioni Mikrotik: MTCNA, MTCRE, MTCWE
Altre certificazioni: Cisco CCNA, KalliopePBX
Preferred Training Centre: Grifonline

Re: Script puntamento - led/acustico - RB411/433

Messaggioda fabianchi » ven 20 nov 2009, 19:54

E pensare che lo avevo provato ma non mi funzionava neanche questo .
Allora ci doveva essere qualche cosa nel mio Mikrotik, infatti mi sono messo a spulciare lo script e trovo che l' interfaccia che per default chimano wlan1 nel mio mikrotik si chiama RadioRb52.
Allora ho messo nello script Radio eccc....
e tutto funziona
Che figura!!!
Tutto questo però era di mio interesse non tanto per il puntamento delle antenne che è certamente una cosa utile, ma per capire se si riusciva a gestire questi 5 led.
E' mia intenzione con il tuo aiuto fare un telecomando con questi 5 led.
Se mi aiuti io faccio l' hardware e poi servirà un programmino che da qualsiasi punto della rete si potrà attivare o disattivare a distanza ad esempio 5 relè.
Questo sistema posto nei monti dove abbiamo i mikrotik è molto utile per sbrogliare varie situazioni senza andare sempre su, magari per riaccendere una radio che si era inceppata o per fare semplicemente un reset a un computer ecc....

ci sentiamo Fabrizio

ps. Ti è arrivato il messaggio privato?? perchè non avevo messo nessun titolo, e se ti è arrivato hai provato ad entrare nella nostra rete?.
fammi sapere
fabianchi
Mikrotik-User 10° Liv
Mikrotik-User 10° Liv
 
Messaggi: 27
Iscritto il: dom 25 ott 2009, 20:23
Località: Siena

Re: Script puntamento - led/acustico - RB411/433

Messaggioda figheras » ven 20 nov 2009, 21:21

Ahhh finalmente....
visto che "la soluzione sta sempre tra la sedia e la scrivania" :lol:
beh certo che di default la radio si chiama wlan1.....questo particolare ti era sfuggito di dirmelo :)

Volevo sapere quale di questi script che ho postato hai utilizzato, in modo da farmi un'idea....
Magari se ti era possibile postare una foto di tutto l'hardware in modo da far capire meglio il sistema come funziona...

Per quanto riguarda il "Telecomando" di cui mi parli, facci una descrizione dettagliata del progetto che desideri realizzare
cosi vediamo un po cosa si puo fare...magari con l'aiuto di tutti gli utenti ;)
Possiamo realizzare una sezione dedicata per queste cose qua....PROGETTI!!

Cmq diciamo che gia esiste una soluzione per gestire tale cosa, delle schede apposite con ingresso gsm che con il telefonino si puo inviare un sms con il comando da far eseguire.....oppure delle schede di rete che possono gestire questi relè in modo da poter fare reboot dovunque siamo(meglio quelle gsm perchè se si blocca un apparato mikrotik significa che il link nn è piu raggiungibile ;))

Purtroppo per quanto riguarda il messaggio privato non l'ho ricevuto, di fatti lo attendevo con ansia per poter vedere di risolvere questa cosa....però sembra che sei stato all'altezza complimenti..

Aspetto tue informazioni in merito alle cose descritte sopra
Siamo tutti ignoranti. Ma non tutti ignoriamo le stesse cose! - Einstein -
Avatar utente
figheras
Staff rosIT
Staff rosIT
 
Messaggi: 1218
Iscritto il: sab 19 set 2009, 20:09
Uso routerOS dalla Versione: v2.9.x
Certificazioni Mikrotik: MTCNA, MTCRE, MTCWE
Altre certificazioni: Cisco CCNA, KalliopePBX
Preferred Training Centre: Grifonline

Re: Script puntamento - led/acustico - RB411/433

Messaggioda pflavio » lun 28 dic 2009, 8:16

Salve a tutti, mi sono appena iscritto a questo bellissimo forum e avrei una domanda da neofita, mi spiegate come inserire stò script in una rb 411 ? Scusate l'ignoranza ma sono alle primissime armi.
Grazie
pflavio
Mikrotik Curious User
Mikrotik Curious User
 
Messaggi: 1
Iscritto il: lun 28 dic 2009, 0:06

Re: Script puntamento - led/acustico - RB411/433

Messaggioda FabiOne » sab 11 set 2010, 14:17

FabiOne
Mikrotik Curious User
Mikrotik Curious User
 
Messaggi: 7
Iscritto il: lun 22 mar 2010, 21:35

Re: Script puntamento - led/acustico - RB411/433

Messaggioda fabrix » sab 23 feb 2013, 16:38

Grazie 1000.
Anche io ho provato lo script e funziona.
Solo 1 domanda.
Ma come si ferma lo script ?
fabrix
Mikrotik-User 10° Liv
Mikrotik-User 10° Liv
 
Messaggi: 15
Iscritto il: gio 6 dic 2012, 22:33

Re: Script puntamento - led/acustico - RB411/433

Messaggioda ciccioprofumato » mer 22 mag 2013, 0:15

ciao a tutti, volevo delle info in merito a questo fantastico script, lho provato e va benissimo, pero' se io spengo lapparato ritorna tutto come prima, a me servirebbe ke lo script sarebbe sempre in funzione, vi spego io devo fare una cpe di test e voglio ke il tutto funziona sempre , anke quando io riavvio, e' solo una cpe per andare ingiro e vedere se il segnale c'e, qualcuno mi puo' aiutare grazie, o se nel caso c'e un auto run dello stesso. grazie..
ciccioprofumato
Mikrotik-Pro 2° Liv
Mikrotik-Pro 2° Liv
 
Messaggi: 321
Iscritto il: mer 20 feb 2013, 1:37

Re: Script puntamento - led/acustico - RB411/433

Messaggioda figheras » mer 22 mag 2013, 12:48

Basta compilare lo script e schedularlo ad ogni startup della RB
Siamo tutti ignoranti. Ma non tutti ignoriamo le stesse cose! - Einstein -
Avatar utente
figheras
Staff rosIT
Staff rosIT
 
Messaggi: 1218
Iscritto il: sab 19 set 2009, 20:09
Uso routerOS dalla Versione: v2.9.x
Certificazioni Mikrotik: MTCNA, MTCRE, MTCWE
Altre certificazioni: Cisco CCNA, KalliopePBX
Preferred Training Centre: Grifonline

Re: Script puntamento - led/acustico - RB411/433

Messaggioda ciccioprofumato » mer 22 mag 2013, 23:15

facile a dirsi, non tanto a farlo, almeno per me.. mi potresti aiutare grazie...
ciccioprofumato
Mikrotik-Pro 2° Liv
Mikrotik-Pro 2° Liv
 
Messaggi: 321
Iscritto il: mer 20 feb 2013, 1:37


Prossimo

Torna a Wiki routerOSiTalia [GUIDE]

Chi c’è in linea

Visitano il forum: Nessuno e 2 ospiti