Ciao Stefano
... ecco qua
Fasi:
1-creazione script
2-settaggio /tool e-mail
3-test script
4-abilitare i log (per trovare eventuali errori)
5-add scheduler
FASE 1
system>script
add
name=backup-script
in source copiare quanto segue:
-----------------------------------start script---------------------------------------------
#### Modificare i valori "xxxx" secondo i vostri parametri di posta!!! ####
#indirizzo di gmail che riceverà il file bakup!!! ####
:local toemail "xxxxxx@gmail.com"
#indirizzo email da cui sarà inviato il file di backup!!!! (se volete potete anche usare lo stesso indirizzo di gmail)
:local fromemail "xxxxx@dominio.com"
#indirizzo smtp del server mail in uscita (nel caso di gmail smtp.gmail.com)!!! ####
:local emailserver "smtp.dominio.com"
############## Lasciare invariato quanto segue e seguire le info "commentate" ##############
:local sysname [/system identity get name]
:local textfilename
:local backupfilename
:local time [/system clock get time]
:local date [/system clock get date]
:local newdate "";
:for i from=0 to=([:len $date]-1) do={ :local tmp [:pick $date $i];
:if ($tmp !="/") do={ :set newdate "$newdate$tmp" }
:if ($tmp ="/") do={}
}
:if ([:find $sysname " "] !=0) do={
:local name $sysname;
:local newname "";
:for i from=0 to=([:len $name]-1) do={ :local tmp [:pick $name $i];
:if ($tmp !=" ") do={ :set newname "$newname$tmp" }
:if ($tmp =" ") do={ :set newname "$newname_" }
}
:set sysname $newname;
}
:set textfilename ($"newdate" . "-" . $"sysname" . ".rsc")
:set backupfilename ($"newdate" . "-" . $"sysname" . ".backup")
:execute [/export file=$"textfilename"]
:execute [/system backup save name=$"backupfilename"]
#ritardo a completamento backup
:delay 2s
#invio copie email (in questo caso 2... qualora si voglia mandare alla casella due copie ma con un diverso oggetto .... vedi più avanti...)
:log info "Emailing backups"
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"textfilename"
:local time [/system clock get time]
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"backupfilename"
#ritardo invio espresso in secondi (10 in questo caso)
:delay 10s
#cancellare copia backup
/file remove $textfilename
/file remove $backupfilename
-----------------------------------end script---------------------------------------------
FASE 2
settare i corretti parametri d'invio anche in:
/tool e-mail>
address: 64.233.166.108 (nel caso di gmail)
port: 587 (porta TLS di gmail normalmente 25)
start-tls: yes (nel caso di gmail, normalmente no)
from:
xxxxx@dominio.com user: ?????
password: ?????
FASE 3
Per testare script
/system> script run backup-script
FASE 4
/system logging>
add
topics=script
action=echo
FASE 5
Per l'esecuzione programmata creare una nuova voce in:
/system scheduler>
A questo punto riceverete sulla vostra casella emal di gmail un messaggio con allegato il file di backup con l'oggetto= [Config Backup] (che potete al limite modificare a vostro piacimento combiando la voce relativa nello script sopra
)
Vi consiglio di creare sulla vostra casella di posta gmail una cartella di nome tipo "Mikrotik Backup" e creare un filtro che sposta tutte l'email in arrivo che hanno come oggetto [Config Backup] nella suddetta cartella!!!
FATTO!!!!
Spero di essere stato abbastanza chiaro
... fatemi sapere se avete dubbi!!!
PS. magari potremmo creare nel forum una sezione dedicata solo agli script .... in effetti potrebbe essere molto comodo ed utile condividere i vari script che usiamo
Ciao a tutti.
Ale
